
This document accompanies the process_wv_20200810.pro script with the objective of fully processing a WorldView satellite scene from the raw zipped imagery to at least an atmospherically corrected scene ready for classification, with the option to orthorectify and mosaic scenes into a single raster per overpass. 

WorldView imagery is delivered from Maxar (previously DigitalGlobe) through the EnhancedView Web Hosting Service (EVWHS). Each scene can be pushed to an FTP site as a zip file, with one zip file per scene. During download, files should be named using the file naming structure defined below. 
















Running this script – here, the basic workflow for opening and running the WorldView script is described. 

1. Open the script in IDL. 
2. Change the rootDir variable in line 46 to the full path name up to an including the “WorldView_Imagery” folder. This is further discussed below in Script components Step #3 Setting the root and working directories.
3. Place the cursor anywhere inside the script editor window and click the “Compile” button along the top. The IDL Console window should print green text to indicate that the script was successfully compiled. If red text appears, there was an error compiling, typically because of a syntax error. 
4. Once the script has successfully compiled, type the name of the script followed by a comma and the name of the area of interest. The area of interest must be in single quotation marks and must match exactly the folder name that contains zip files for the area of interest (including capitalization, underscores, etc.). For example, after compiling, the following should be entered in the IDL console window: 

process_wv_20200810, 'St_Joe'




























Script components – here, the code is described line-by-line and the necessary file structure is explained in detail. 

1. Defining the procedure and compiling IDL. An IDL script is known as a procedure, and it must be defined for the script to run properly. The start of this calls PRO which defines the procedure called process_wv_20200810. After the procedure name, there is a comma and then the input variables. Here, only one input variable is required, called aoi. This variable is the area of interest to be processed in the script. When defining this variable, it is important to keep in mind that the variable name must follow exactly the AOI name of the folder that contains the input files (i.e. including capitalization, underscores, etc.).  

  PRO process_wv_20200810, aoi

In addition to defining the procedure, IDL must be compiled. A COMPILE_OPT is a statement which is processed by the IDL compiler to change the behavior of the compiler. Specifying IDL2 sets two flags for the IDL compiler, DEFINT32 and STRICTARR. The DEFINT32 flag sets the default size of IDL integers to be 32-bits rather than 16-bits. The STRICTARR flag prevents IDL from using parentheses for array indexing. 


  ; Compile IDL
  COMPILE_OPT IDL2


2. Defining the Rayleigh Exponent. The Rayleigh exponent is one of the three components of atmospheric correction that can be adjusted. The Rayleigh exponent is used to compute the scattering factor and to compute the subtraction values for each band. A higher Rayleigh exponent will result in more correction applied to the imagery, whereas a lower Rayleigh exponent will result in less correction applied to the imagery. At several sites along the Florida coast and in the Chesapeake Bay, a Rayleigh exponent of 4.75 was found to be optimal for creating separability within the different spectral classes while maintaining positive reflectance values across all bands. However, this is a component that may need to be adjusted at other sites or for different time periods. 


  ; Define the Rayleigh exponent to use for atmospheric correction
  rayleighExp = 4.75


3. Setting the root and working directories. Unless the Rayleigh exponent requires adjusting, this should be the only line of code that needs to be manually changed before compiling and calling the script. 


  ; Define AOI and change working directory
  PRINT, 'Processing satellite imagery for ' + aoi
  rootDir = 'E:\Estuary_Seagrass\WorldView_Imagery\'
  workingDir = rootDir + aoi
[image: ]The rootDir line should specify the full path of the WorldView_Imagery  folder. Within that folder, a separate folder should exist for each AOI. Within each AOI folder (i.e. “Chesapeake_Aeronet” in the figure to the right), a folder should exist called “1_Zip_File.” These zip files should be named with the following naming convention:


AOI_SENSOR_YYYYMMDD_N.zip

AOI = area of interest (exact same name as AOI folder)
SENSOR = RE
YYYYMMDD = The date of image acquisition 
N = An index which is set to 1 except when there are multiple scenes collected per day


Additionally, the WorldView_Imagery folder should contain a folder called InputData which contains a global DEM available with every ENVI/IDL installation (GMTED2010.jp2) and two subfolders: estuaries and extents. These subfolders contain an XML of the estuary boundary for the given AOI and an XML of the bounding box for the given AOI. Documentation for creating these input files are available at the DOI specified in the associated manuscript. The workingDir will then be set to the AOI folder within the rootDir. 


4. Suppressing automated messages. ENVI will automatically print many messages to the IDL Console. This line of code silences theses automated console messages. Thus, the only text printed to the IDL console as the procedure is run will be generated from within the script and provide updates on the progress of the script processing. 
  

  ; Suppress automated console messages
  !quiet = 1


5. Listing zip files. This line of code finds all zip files contained within workingDir and returns their full path filename into an array. 


  ; List zip files in 1_Zip_File
  zipFiles = FILE_SEARCH(workingDir + '\1_Zip_File\', '*.zip', /FULLY_QUALIFY_PATH)


6. Loop through zip files to process each scene. Each satellite overpass is collected in a scene, which is then broken up into tiles. We first need to loop through the scenes listed in zipFiles and unzip them. This will contain the tiles which we will then loop through and process through to atmospheric correction. 


  ; Loop through each file in zipFiles
  FOR i = 0, N_ELEMENTS(zipFiles) - 1 DO BEGIN
[bookmark: _Hlk29993986]7. Initiate ENVI and set temporary directory. First, ENVI is initiated from within IDL. This will open an ENVI window (throughout processing of this script, an ENVI window may open and display a progress bar, but there is no need to interact with the ENVI window). Additionally, IDL and ENVI create a lot of temporary files during processing. In an effort to prevent storage issues, a folder is created and designated for temporary files throughout processing. This folder can then be deleted after the script has run.


  ; Initiate ENVI session
  e = ENVI()


  ; Create and set a temporary folder
  prefs = e.Preferences
  tempFolder = FILEPATH('tempFolder\', ROOT_DIR = workingDir)
  FILE_MKDIR, tempFolder
  prefs['directories and files:temporary directory'].VALUE = tempFolder


8. Read in input files. The required input files were those listed in the InputData folder mentioned previously. The extent and estuaries XML files will be read in as ROI files, and the global DEM will be read in as a raster file. 


  ; Read in required input files
  ; extentRoi outlines the extent of the area of interest
  extentRoiPath = FILEPATH('InputData\extents\' + aoi + '_extent.xml', ROOT_DIR = rootDir)
  extentRoi = e.OpenRoi(extentRoiPath)
  ; estuariesRoi outlines the estuary for the area of interest 
  estuariesRoiPath = FILEPATH('InputData\estuaries\' + aoi + '_estuaries.xml', ROOT_DIR = rootDir)
  estuariesRoi = e.OpenRoi(estuariesRoiPath)
  ; demInput is a global DEM raster file 
  demFile = FILEPATH('InputData\GMTED2010.jp2', ROOT_DIR = rootDir)
  demInput = e.OpenRaster(demFile)


9. Subset to the ith zip file and unzip. The zip file currently being iterated through will be unzipped into a new folder that will be created by the script. In order to know what to name these new folders, the fileBasename is defined.  Once the basename is defined, the zip file can be unzipped into a new folder under the AOI folder called 2_Raw_Data. IDL has a file size limit on what it will unzip, therefore we use IDL to call a powershell command. Several command windows will open on your computer during this unzipping process. This is typically the longest step, so please have patience. Some WorldView scenes containing many tiles may take upwards of an hour to unzip. Despite the time-intensity of this step, it just needs to be performed once for each zip file and will automatically unzip your data rather than a user having to unzip by hand for each scene. You’ll also notice an IF statement before unzipping. IDL does not allow for an output file to have the same name as an existing file, and there is no option to overwrite the output like in other programming languages. These IF statements will be used any time an output is created. If the file already exists, the code within the IF statement will not be executed. Therefore, if you would like to overwrite a file, it must be deleted manually before compiling and running the script. 


  ; Subset to the ith zip file
  zipFile = zipFiles[i]
  fileBasename = FILE_BASENAME(zipFile, '.zip')
  ; Unzip the ith zip file into 2_Raw_Data
  PRINT, STRING(9B) + 'Unzipping raw imagery for file: ' + STRCOMPRESS(fileBasename + ' (File ' + STRING(i + 1) + ' of ' + STRING(N_ELEMENTS(zipFiles)) + ')')
  IF ~ FILE_TEST(FILEPATH('2_Raw_Data/' + fileBasename + '_rawData', ROOT_DIR = workingDir)) THEN BEGIN
    ; Create a string for the output folder
    unzipFile = FILEPATH('2_Raw_Data/' + fileBasename + '_rawData', ROOT_DIR = workingDir)
    ; Create a string for the SPAWN command input
    spawnInput = "powershell.exe Expand-Archive -Path " + zipFile + " -DestinationPath " + unzipFile + " -Verbose"
    ; Call powershell from IDL to unzip the
    SPAWN, spawnInput
  ENDIF


10. List tiles within the scene. Now that the scene has been unzipped, the tiles will be listed. These tiles have a .TIL file extension. ENVI knows to read both the raster image and the associated metadata file. This line of code finds all .TIL files contained within the newly created 2_Raw_Data folder for the given scene and returns their full path filename into an array. 


  ; List .TIL files for the current scene
  satFiles = FILE_SEARCH(FILEPATH('2_Raw_Data/' + fileBasename + '_rawData', ROOT_DIR = workingDir), '*M1BS*' + '*.TIL', /FULLY_QUALIFY_PATH)












11. Generate arrays to output scene information. This script will output information about each tile contained within the scene. The next section of code defines arrays to populate with varying information which will later be populated for each tile and saved as a CSV file. 


  ; Define an array to populate with red edge values for each tile
  rededgeList = MAKE_ARRAY(N_ELEMENTS(satFiles), 1, /FLOAT, VALUE = -9999)
  ; Define arrays to populate with image information
  tileFilename = MAKE_ARRAY(N_ELEMENTS(satFiles), 1, /STRING, VALUE = 'NA')
  tileViewAngle = MAKE_ARRAY(N_ELEMENTS(satFiles), 1, /FLOAT, VALUE = -9999)
  tileSunAngle = MAKE_ARRAY(N_ELEMENTS(satFiles), 1, /FLOAT, VALUE = -9999)
  tileREdgeAnchor = MAKE_ARRAY(N_ELEMENTS(satFiles), 1, /FLOAT, VALUE = -9999)
  tileRayleigh = MAKE_ARRAY(N_ELEMENTS(satFiles), 1, /FLOAT, VALUE = -9999)
  tileProcessingTime = MAKE_ARRAY(N_ELEMENTS(satFiles), 1, /STRING, VALUE = 'NA')


12. Loop through each tile. Begin the next for-loop and loop through each tile within the scene and process it. Update the IDL console with script progress. 


  ; Loop through each tile, read it in, and process
  FOR j = 0, N_ELEMENTS(satFiles) - 1 DO BEGIN


    ; Print progress of the loop
    PRINT, STRING(9B) + STRING(9B) + 'Processing steps 1 through 7 for tile' + STRCOMPRESS(STRING(j + 1) + ' of ' + STRING(N_ELEMENTS(satFiles)))
    ; Print progress of the loop
    PRINT, STRING(9B) + STRING(9B) + STRING(9B) + STRCOMPRESS('Reading in raster as a WorldView scene (Step 1 of 10)')











13. Read in each tile and define an output name. Each tile is read in as a raster and a new outputFile name is defined to reflect the index of the tile being processed. 


  ; Read in .TIL image
  file = satFiles[j]
  raster = e.OpenRaster(file)
  ; Define outputFile for saving rasters
  outputFile = STRCOMPRESS(fileBasename + '_' + STRING(j + 1), /REMOVE_ALL)


14. Test if and how much the satellite tile intersects the estuaries ROI. Before processing the tile, the script first checks that the tile intersects the estuaries ROI read in above, and then checks how much they overlap. If they overlap by at least 20%, the raster is first cropped to the extent ROI before continuing processing. 


  ; Determine if the tile is within the estuariesRoi extent
  rasterRoiExtent = estuariesRoi.GetExtent(raster)


  ; If raster does not fall within the extent of estuariesRoi, do not continue processing this file
  IF(rasterRoiExtent EQ !NULL) THEN BEGIN
        
        
    ; Print a statement that the tile will not be processed
    PRINT, STRING(9B) + STRING(9B) + 'This tile will not be processed as it does not fall within the ROI for the given estuary.'


    ; If raster does fall within the extent of estuariesRoi, continue processing.
    ENDIF ELSE BEGIN

           
    ; Check if the tile covers at least 20% of extentRoi before continuing processing
    ; Determine the number of pixels in extentRoi that intersect demInput
    pixelsInROI = extentRoi.PixelCount(demInput)
    ; Find the area of these pixels assuming each DEM pixel is approximately 900 m, which is sufficient for the current task
    areaInROI = pixelsInROI * (900 ^ 2)
    ; Determine the number of pixels in extentRoi that intersect raster
    pixelsOverlap = extentRoi.PixelCount(raster)
    ; Find the area of these pixels based on a spatial resolution of 2 m
    areaOverlap = pixelsOverlap * (2 ^ 2)
    ; Find the percent overlap between areaInROI and areaOverlap 
    pctOverlap = FLOAT(areaOverlap) / FLOAT(areaInROI)        


    ; If the scene covers less than 20% of the ROI, do not continue processing
    IF(pctOverlap LT 0.2) THEN BEGIN

      ; Print a statement that the tile will not be processed
      PRINT, STRING(9B) + STRING(9B) + 'This tile will not be processed as it covers less than 20% of the ROI for the given estuary.'

        
      ; If raster covers more than 20% of the extent of estuariesRoi, continue processing.
      ENDIF ELSE BEGIN
          

        ; Print a statement that the tile will be processed
        PRINT, STRING(9B) + 'This tile will be cropped to the ROI for the given estuary and processed.'
        ; Crop by extentRoi to reduce processing
        PRINT, STRING(9B) + STRING(9B) + STRING(9B) + 'Masking and cropping scene to match AOI extent (Step 2 of 10)'
        rasterCropped = ENVIROIMaskRaster(raster, extentRoi)


15. Update metadata and perform radiometric calibration. While level 1B imagery included a relative radiometric correction, the calibration factors provided with the WorldView-2 imagery required updating. The image gain and offset values, defined as the absolute radiometric calibration band dependent adjustment factors, required an additional adjustment factor not provided with the imagery. DigitalGlobe explains that gain and offset values included in the metadata are based off a pre-flight calibration. Since launch, an extensive vicarious calibration campaign has been performed to provide adjustments to the pre-launch values. They also note that these values are revisited annually. Before radiometric calibration, the metadata are updated to reflect these changes. First, the ENVI Task is defined as RadiometricCalibration and the input raster is specified. Documentation on this task can be found at: https://www.harrisgeospatial.com/docs/ENVIRadiometricCalibrationTask.html. 


  ; Update metadata and perform radiometric calibration
  PRINT, STRING(9B) + STRING(9B) + STRING(9B) + 'Applying radiometric calibration (Step 3 of 10)'
  IF ~ FILE_TEST(FILEPATH('3_Rad_Cal/' + outputFile + '_radCal/' + outputFile + '_radCal.til', ROOT_DIR = workingDir)) THEN BEGIN
    ; Define the task
    Task_RadCal = ENVITask('RadiometricCalibration')
    ; Open input raster
    Task_RadCal.INPUT_RASTER = rasterCropped
The first metadata tag specified is the 'DATA IGNORE VALUE' tag. The code checks to see if the metadata already contains this tag. If it does, the tag is updated to 999999. If it does not have this tag, it is added as 999999. 


    ; Add data ignore value
    metadata = rasterCropped.Metadata
    IF (metadata.HasTag ('DATA IGNORE VALUE')) THEN BEGIN
      metadata.UpdateItem, 'DATA IGNORE VALUE', 999999
    ENDIF ELSE BEGIN
      metadata.AddItem, 'DATA IGNORE VALUE', 999999
    ENDELSE


Next, the absolute calibration factor and the effective bandwidth need to be extracted from the IMD file included with the imagery. These values are required to update the gains and offsets provided in the metadata.  


    ; Extract absolute calibration factor and effective bandwidth for the scene
    imd_files = FILE_SEARCH(FILEPATH('2_Raw_Data/' + fileBasename + '_rawData', ROOT_DIR = workingDir), '*M1BS*' + '*.IMD')
    imd_file = imd_files[j]
    ; Read in metadata
    OPENR, unit, imd_file, /GET_LUN
      array = ''
      line = ''
      WHILE NOT EOF(unit) DO BEGIN & $
        READF, unit, line & $
        array = [array, line] & $
      ENDWHILE
    FREE_LUN, unit
    ; Extract the absolute calibration factor and effective bandwidth for each band
    absCal = FLOAT(STRMID(array[WHERE(STRMATCH(array, '*absCalFactor*'))],16,17))
    effBW = FLOAT(STRMID(array[WHERE(STRMATCH(array, '*effectiveBandwidth*'))],22,23))










The extracted absCalFactor and effectiveBandwidth are used along with the new scale factors provided by DigitalGlobe to compute updated gain and offset values. These are then updated in the metadata according to whether the sensor of interest is WorldView-2 or WorldView-3. 


    ; Adjust gains and offsets according to the sensor
    IF STRMATCH(metadata['SENSOR TYPE'], 'WorldView-2') THEN BEGIN
      newScaleFactors = [1.151, 0.988, 0.936, 0.949, 0.952, 0.974, 0.961, 1.002]
      metadata.UpdateItem, 'DATA GAIN VALUES', newScaleFactors * (absCal / effBW)
      metadata.UpdateItem, 'DATA OFFSET VALUES', [-7.478, -5.736, -3.546, -3.564, -2.512, -4.120, -3.300, -2.891]
    ENDIF ELSE IF STRMATCH(metadata['SENSOR TYPE'], 'WorldView-3') THEN BEGIN
      newScaleFactors = [0.905, 0.940, 0.938, 0.962, 0.964, 1.000, 0.961, 0.978]
      metadata.UpdateItem, 'DATA GAIN VALUES', newScaleFactors * (absCal / effBW)
      metadata.UpdateItem, 'DATA OFFSET VALUES', [-8.604, -5.809, -4.996, -3.649, -3.021, -4.521, -5.522, -2.992]
    ENDIF


Finally, the radiometric calibration can be run. The calibration type is set to Top-of-Atmosphere Reflectance and the task is executed. A new folder is created, and the results are output to this folder. 


    ; Set parameters for radiometric calibration and run task
    Task_RadCal.CALIBRATION_TYPE = 'Top-of-Atmosphere Reflectance'
    Task_RadCal.Execute
    ; Output results into new folder
    radCalOutput = Task_RadCal.OUTPUT_RASTER
    FILE_MKDIR, FILEPATH('3_Rad_Cal/' + outputFile + '_radCal', ROOT_DIR = workingDir)
    radCalOutput.Export, FILEPATH('3_Rad_Cal/' + outputFile + '_radCal/' + outputFile + '_radCal.til', ROOT_DIR = workingDir), 'ENVI'
  ENDIF







16. Divide pixel values by pi. All pixel values across all bands are then divided by pi. Unfortunately, IDL does not offer a simplified workflow to apply band math across all bands, therefore, the raster must be deconstructed into single band rasters, band math must be applied to each raster, and the bands must be stacked back together. First, the output from the previous step is read in as a raster. 

    
  ; Convert from R to normalized water leaving reflectance by dividing all values of each band by pi
  PRINT, STRING(9B) + STRING(9B) + STRING(9B) + 'Converting R to Rrs (Step 4 of 10)'
  IF ~ FILE_TEST(FILEPATH('4_R_To_Rrs/' + outputFile + '_rToRrs/' + outputFile + '_rToRrs.til', ROOT_DIR = workingDir)) THEN BEGIN
    rrsRasterFile = workingDir + '/3_Rad_Cal/' + outputFile + '_radCal/' + outputFile + '_radCal.til'
    rrsRaster = e.OpenRaster(rrsRasterFile)


An empty dictionary and an empty list are defined to populate results for each band. 


    ; Define an empty dictionary and an empty list to populate with results for each band
    rrsAggregator = Dictionary()
    rrsList = List()


The ENVI Task is defined as ExtractBandsFromRaster to extract each individual band from the stacked raster. Documentation on this task can be found at: https://www.harrisgeospatial.com/docs/ENVIExtractBandsFromRasterTask.html.


    ; Extract each band from rrsRaster
    Task_ExtractBands = ENVITask('ExtractBandsFromRaster')
    Task_ExtractBands.INPUT_RASTER = rrsRaster
    Task_ExtractBands.Execute













Each band is looped through and band math is applied. These results are added to the dictionary and list initiated previously. Documentation on this task can be found at: https://www.harrisgeospatial.com/docs/ENVIPixelwiseBandMathRasterTask.html.


    ; Loop through each band and apply band math
    FOREACH k, Task_ExtractBands.OUTPUT_RASTERS, k_index DO BEGIN
      ; Apply band math to divide all pixel values by pi
      Task_BandMath = ENVITask('PixelwiseBandMathRaster')
      Task_BandMath.INPUT_RASTER = k
      Task_BandMath.EXPRESSION = 'b1 / !pi'
      Task_BandMath.Execute
      ; Add results to rrsList
      rrsList.Add, Task_BandMath.OUTPUT_RASTER, /EXTRACT
      rrsAggregator.OUTPUT = rrsList
    ENDFOREACH


The ENVI Task is defined as BuildBandStack to combine all bands into a stacked raster. The associated metadata is added to the new output from the band math stack. This raster is then output to a new folder. Documentation on this task can be found at: https://www.harrisgeospatial.com/docs/ENVIBuildBandStackTask.html.

    
    ; Stack each band back together using BuildBandStack
    Task_Stack = ENVITask('BuildBandStack')
    Task_Stack.INPUT_RASTERS = rrsAggregator.OUTPUT
    Task_Stack.OUTPUT_RASTER_URI = "*"
    Task_Stack.Execute
    bandMathOutput = Task_Stack.OUTPUT_RASTER
    ; Transfer metadata from rrsRaster to bandMathOutput
    FOR metadataTag = 0, N_ELEMENTS(rrsRaster.Metadata.Tags) - 1 DO BEGIN
      IF bandMathOutput.Metadata.HasTag (rrsRaster.Metadata.Tags[metadataTag]) THEN BEGIN
        bandMathOutput.Metadata.UpdateItem, rrsRaster.Metadata.Tags[metadataTag], rrsRaster.Metadata[rrsRaster.Metadata.Tags[metadataTag]]
      ENDIF ELSE BEGIN
        bandMathOutput.Metadata.AddItem, rrsRaster.Metadata.Tags[metadataTag], rrsRaster.Metadata[rrsRaster.Metadata.Tags[metadataTag]]
      ENDELSE
    END
    ; Output results into new folder
    FILE_MKDIR, FILEPATH('4_R_To_Rrs/' + outputFile + '_rToRrs/', ROOT_DIR = workingDir)
    bandMathOutput.Export, FILEPATH('4_R_To_Rrs/' + outputFile + '_rToRrs/' + outputFile + '_rToRrs.til', ROOT_DIR = workingDir), 'ENVI'
  ENDIF
17. Find the red edge anchor value for the tile. As mentioned previously, there are three main components of dark object subtraction atmospheric correction that can be adjusted. We have already specified the Rayleigh exponent which is one component. The other two components include the wavelength at which the scattering factor is computed, and the value applied to this wavelength to represent atmospheric contamination. For this project, the red edge band is defined as the band representative of atmospheric contamination. NIR bands are also commonly used, but we have found these satellites to not be sensitive enough to collect information in these wavelengths, meaning their reflectance is often zero over dark targets. Thus, the red edge band was chosen. In order to attempt to automate the dark object subtraction workflow, the raster tile is subset both spatially and spectrally before defining the lowest 5% of the red edge distribution as the darkest pixels within the scene. First, the AOI_estuaries.XML ROI read in earlier is used to spatially subset the scene. This step generally separates water and land. 


  ; Get just water pixels by masking the raster by our ROI to subset spatially and masking by NDWI values to subset spectrally
  PRINT, STRING(9B) + STRING(9B) + STRING(9B) + 'Masking raster image to just water pixels (Step 5 of 10)'
  IF ~ FILE_TEST(FILEPATH('5_Mask_Raster/' + outputFile + '_maskRaster/' + outputFile + '_maskRaster.til', ROOT_DIR = workingDir)) THEN BEGIN
    shpMaskRasterFile = FILEPATH('4_R_To_Rrs/' + outputFile + '_rToRrs/' + outputFile + '_rToRrs.til', ROOT_DIR = workingDir)
    shpMaskRasterInput = e.OpenRaster(shpMaskRasterFile)
    shpMaskRaster = ENVIROIMaskRaster(shpMaskRasterInput, estuariesRoi)






















The estuaries shapefile leaves some pixels along the shoreline that still contain land signal. Thus, an NDWI threshold is applied. Pixels with an NDWI value above zero are classified as water; pixels at or below zero are classified as land. The ENVIPixelwiseBandMathRaster function is used to compute NDWI as a band ratio using the NIR and Green bands. The 'MaskRaster' ENVI Task is called to mask pixels with an NDWI value at or below zero. Results are output to a new folder. Documentation on this task can be found at: https://www.harrisgeospatial.com/docs/ENVIMaskRaster.html.


    ; Calculate NDWI on shpMaskRaster
    Task_NDWI = ENVITask('PixelwiseBandMathRaster')
    Task_NDWI.INPUT_RASTER = shpMaskRaster
    Task_NDWI.EXPRESSION = 'float(b3 - b7) / float(b3 + b7)'
    Task_NDWI.Execute
    rasterNDWI = Task_NDWI.OUTPUT_RASTER
    ; Create a mask raster based on an NDVI threshold
    ndwiThreshold = [0]
    ndwiThresholdRaster = ENVIBinaryLTThresholdRaster(rasterNDWI, ndwiThreshold)
    ; Apply ndwiThresholdRaster as a threshold mask on shpMaskRaster
    Task_Mask = ENVITask('MaskRaster')
    Task_Mask.DATA_IGNORE_VALUE = 999999
    Task_Mask.INPUT_MASK_RASTER = ndwiThresholdRaster
    Task_Mask.INPUT_RASTER = shpMaskRaster
    Task_Mask.INVERSE = 'TRUE'
    Task_Mask.Execute
    ; Output results into new folder
    maskOutput = Task_Mask.OUTPUT_RASTER
    FILE_MKDIR, FILEPATH('5_Mask_Raster/' + outputFile + '_maskRaster/', ROOT_DIR = workingDir)
    maskOutput.Export, FILEPATH('5_Mask_Raster/' + outputFile + '_maskRaster/' + outputFile + '_maskRaster.til', ROOT_DIR = workingDir), 'ENVI'
  ENDIF
 














Next, the atmospheric correction reference value is computed for the given tile. The masked raster created in the previous step is read in, and the red edge band data is extracted. These values are subset to just those less than 999999 (our data ignore value) and sorted. The lowest 5% of the distribution is retained and this value is reduced by a magnitude of two. This represents the red edge anchor value for the given tile. 


  ; Extract band six (red edge) values and save to list
  PRINT, STRING(9B) + STRING(9B) + STRING(9B) + 'Computing atmospheric correction reference value (Step 6 of 10)'
  ; Read in results from 5_Mask_Raster
  redEdgeFile = FILEPATH('5_Mask_Raster/' + outputFile + '_maskRaster/' + outputFile + '_maskRaster.til', ROOT_DIR = workingDir)
  redEdgeInput = e.OpenRaster(redEdgeFile)
  ; Subset to red edge values and get data greater than 999999 (our data ignore value)
  redEdgeValues = redEdgeInput.GetData(BANDS = [5])
  redEdgeValuesSubset = redEdgeValues[WHERE(redEdgeValues GT 999999)]
  redEdgeValuesSort = redEdgeValuesSubset[SORT(redEdgeValuesSubset)]
  ; Retrieve half of the lowest 5% of the data within the red edge
  redEdgeAnchor = MEDIAN(redEdgeValuesSort[0: (N_ELEMENTS(redEdgeValuesSubset) / 20) - 1]) / 2



























18. Extract and export scene information. The arrays created near the beginning of the script are populated with information about the scene. This metadata file is parsed to find scene information including off nadir view angle and mean sun elevation. These parameters, and other information about the current processing are used to populate arrays. After populating these arrays, the script exits the IF statement that checks if the tile covers at least 20% of the scene, the IF statement that checks if the tile covers any portion of the scene, and the FOR loop that iterates through tiles contained within the scene. The script will loop bac through the FOR loop until all tiles within the scene are processed before moving to the next step. 


        ; Get information about the scene and populate arrays
        imd_files = FILE_SEARCH(FILEPATH('2_Raw_Data/' + fileBasename + '_rawData', ROOT_DIR = workingDir), '*M1BS*' + '*.IMD')
        imd_file = imd_files[j]
        ; Read in metadata
        OPENR, unit, imd_file, /GET_LUN
          array = ''
          line = ''
          WHILE NOT EOF(unit) DO BEGIN & $
            READF, unit, line & $
            array = [array, line] & $
          ENDWHILE
        FREE_LUN, unit
        ; Extract the meanOffNadirViewAngle and meanSunEl for the scene
        tileFilename[j] = outputFile
        tileViewAngle[j] = FLOAT(STRMID(array[WHERE(STRMATCH(array, '*meanOffNadirViewAngle*'))],24,27))
        tileSunAngle[j] = FLOAT(STRMID(array[WHERE(STRMATCH(array, '*meanSunEl*'))],13,16))
        tileREdgeAnchor[j] = redEdgeAnchor
        tileRayleigh[j] = rayleighExp
        tileProcessingTime[j] = SYSTIME()
  
      ENDELSE
  
    ENDELSE
  
  ENDFOR










After looping though each tile contained within the scene, scene information is saved as a CSV file with one row per tile.


  ; Save scene information as a CSV file
  PRINT, STRING(9B) + STRING(9B) + STRING(9B) + 'Outputing file information as a CSV file (Step 7 of 10)'
  IF ~ FILE_TEST(FILEPATH('File_Information/' + STRMID(outputFile, 0, STRLEN(outputFile) - 2) + '_fileInformation.csv', ROOT_DIR = workingDir)) THEN BEGIN
    ; Create a CSV file of the results
    FILE_MKDIR, FILEPATH('File_Information/', ROOT_DIR = workingDir)
    fileinfo_output = FILEPATH('File_Information/' + STRMID(outputFile, 0, STRLEN(outputFile) - 2) + '_fileInformation.csv', ROOT_DIR = workingDir)
    WRITE_CSV, fileinfo_output, tileFilename, tileViewAngle, tileSunAngle, tileREdgeAnchor, tileRayleigh, tileProcessingTime, $
    HEADER = ['FILENAME', 'VIEWANGLE', 'SUNANGLE', 'REDEDGEANCHOR', 'RAYLEIGH', 'PROCESSINGTIME']
  ENDIF





























19. Find the red edge anchor value for the scene. Previously, we found the red edge anchor value for the tile. Now, we will find the red edge anchor value for the scene. It is likely that not all tiles will contain an area of dark water truly representative of atmospheric contamination. Therefore, this script finds the darkest pixels possible within a tile and the minimum of these dark pixels for all tiles within the scene is used to represent the atmospheric contamination at the time of image acquisition. This is an attempt to correct for any tiles that may not contain dark water. Given that the lowest 5% of pixel values was extracted, this approach is appropriate when at least 5% of the entire scene contains dark water. If more than 95% of the entire scene is not dark water, this approach is not recommended. The wavelengths are defined for WorldView-2 and WorldView-3, and the minimum of all tile red edge anchor values is found. This minimum value is used to compute the scatteringFactor based on the wavelength at the red edge band (band 6 for WorldView) and the rayleighExp defined at the beginning of the script. The scattering factor is then applied to the wavelength at each band to determine how much reflectance is subtracted at each pixel. 


  ; Find the minimum rededge value for the entire overpass and compute the atmospheric correction values
  ; Determine which satellite is being processed to define wavelengths
  wvFilename = FILE_BASENAME(zipFiles[i], '.zip')
  sensorName = STRMID(wvFilename,STRPOS(wvFilename, 'WV'), 3)
  IF(sensorName EQ 'WV2') THEN BEGIN
    wavelengths = [427.3,477.9,546.2,607.8,658.8,723.7,832.5,908.0]
  ENDIF ELSE BEGIN
    wavelengths = [425.0,480.0,545.0,605.0,660.0,725.0,832.5,950.0]
  ENDELSE
  ; Find the minimum value from rededgeList and compute atmospheric correction values
  minRedEdgeAnchor = MIN(tileREdgeAnchor)
  ; Compute the scattering factor based on the minRededge value
  scatteringFactor = wavelengths[5] ^ rayleighExp * minRedEdgeAnchor
  ; Use the scatteringFactor to compute the correction values for each band
  atmCorrValues = MAKE_ARRAY(N_ELEMENTS(wavelengths), 1, /FLOAT, VALUE = 999999)
  FOR j = 0, N_ELEMENTS(wavelengths) - 1 DO BEGIN
    atmCorrValues[j] = scatteringFactor / wavelengths[j] ^ rayleighExp
  ENDFOR












20. Apply atmospheric correction. Most of the processing was done on a tile-by-tile basis. However, to determine the red edge anchor value, we had to determine the red edge value for each tile before coming out of the FOR loop to determine the minimum red edge value for the entire scene. Now that we have determine the red edge anchor value for the entire scene and computed the atmospheric correction values for each band, we have to go back into a FOR loop to apply these corrections to each tile. Results from 4_R_To_Rrs are listed and looped through. 

  
  ; List processed files from 4_R_To_Rrs for further processing 
  rToRrs_files = FILE_SEARCH(workingDir + '\4_R_To_Rrs\', '*.TIL')


  ; Loop through each tile in rToRrs_files and apply additional processing 
  FOR j = 0, N_ELEMENTS(rToRrs_files) - 1 DO BEGIN
      
      
  ; Update the progress of the loop
  PRINT, STRING(9B) + STRING(9B) + 'Processing step 8 through 10 for tile' + STRCOMPRESS(STRING(j + 1) + ' of ' + STRING(N_ELEMENTS(satFile)))

    
  ; Define outputFile
  outputFile = STRMID(FILE_BASENAME(rToRrs_files[j],'.TIL'), 0,STRLEN(FILE_BASENAME(rToRrs_files[j],'.TIL'))-7)
      























The 4_R_To_Rrs output is read in as a raster and the DarkSubtractionCorrection ENVI Task is called. The values used for DOS are the atmCorrValues defined in the previous step, outside the current for-loop. Results are output to a new folder. Documentation on this task can be found at: https://www.harrisgeospatial.com/docs/ENVIDarkSubtractionCorrectionTask.html.


  ; Apply atmospheric correction
  PRINT, STRING(9B) + STRING(9B) + STRING(9B) + STRCOMPRESS('Applying atmospheric correction (Step 8 of 10)')
  IF ~ FILE_TEST(FILEPATH('6_Atm_Corr/' + outputFile + '_atmCorr/' + outputFile + '_atmCorr.til', ROOT_DIR = workingDir)) THEN BEGIN
    ; Read in raster results from 4_R_To_Rrs as atmospheric correction input
    atmCorrFile = rToRrs_files[j]
    atmCorrInput = e.OpenRaster(atmCorrFile[0])
    ; Apply the DarkSubtractionCorrection task
    Task_atmCorr = ENVITask('DarkSubtractionCorrection')
    Task_atmCorr.INPUT_RASTER = atmCorrInput
    Task_atmCorr.VALUES = atmCorrValues
    Task_atmCorr.Execute
    ; Output results into new folder
    atmCorrOutput = Task_atmCorr.OUTPUT_RASTER
    FILE_MKDIR, FILEPATH('6_Atm_Corr/' + outputFile + '_atmCorr/', ROOT_DIR = workingDir)
    atmCorrOutput.Export, FILEPATH('6_Atm_Corr/' + outputFile + '_atmCorr/' + outputFile + '_atmCorr.til', ROOT_DIR = workingDir), 'ENVI'
  ENDIF





















21. OPTIONAL – RPC Orthorectification. This step is set to optional because it is not required for classification and can take an extremely long time to process. Note, this step is required if mosaicing is desired. The atmospheric correction output is read in as input before calling the RPCOrthorectification ENVI Task. The output pixel size is set to the native resolution of the imagery, 2 m. The results are output to a new folder. Documentation on this task can be found at: https://www.harrisgeospatial.com/docs/RPCOrthorectification.html. To run this portion of the code, uncomment this chunk (Ctrl + ;) and re-compile. After applying RPC orthorectification, the IF statement checking the overlap between the raster and the extent ROI is closed and the FOR loop iterating through each tile in the scene.


[bookmark: _Hlk29997548]    ; OPTIONAL -- Apply RPCOrthorectification
    PRINT, STRING(9B) + STRING(9B) + STRING(9B) + STRCOMPRESS('Applying RPC Orthorectification (Step 9 of 10)')
    IF ~ FILE_TEST(FILEPATH('7_RPC_Ortho/' + fileBasename + '_rpcOrtho/' + fileBasename + '_rpcOrtho.til', ROOT_DIR = workingDir)) THEN BEGIN
      ; Read in results from atmospheric correction
      rpcOrthoFile = FILEPATH('6_Atm_Corr/' + fileBasename + '_atmCorr/' + fileBasename + '_atmCorr.til', ROOT_DIR = workingDir)
      rpcOrthoInput = e.OpenRaster(rpcOrthoFile, DATA_IGNORE_VALUE = 999999)
      ; Apply the RPCOrthorectification task
      Task_rpcOrtho = ENVITask('RPCOrthorectification')
      Task_rpcOrtho.INPUT_RASTER = rpcOrthoInput
      Task_rpcOrtho.DEM_RASTER = demInput
      Task_rpcOrtho.OUTPUT_PIXEL_SIZE = [6.5,6.5]
      Task_rpcOrtho.Execute
      ; Output results into new folder
      rpcOrthoOutput = Task_rpcOrtho.OUTPUT_RASTER
      FILE_MKDIR, FILEPATH('7_RPC_Ortho/' + fileBasename + '_rpcOrtho/', ROOT_DIR = workingDir)
      rpcOrthoOutput.Export, FILEPATH('7_RPC_Ortho/' + fileBasename + '_rpcOrtho/' + fileBasename + '_rpcOrtho.til', ROOT_DIR = workingDir), 'ENVI'
        
    ENDIF   
           
  ENDFOR








22. OPTIONAL – Mosaic tiles into a single scene. If tiles are orthorectified, then can be mosaicked into a single raster that includes all tiles within the scene. Because this is done on a scene-by-scene basis and not a tile-by-tile basis, we exit the for-loop that was iterating through the tiles. While still inside the for-loop that is iterating through scenes, we first list any tiles from the RPC Orthorectification output for the given scene as input files for mosaicing. An empty list is initiated to populate with these rasters. This list of filenames is iterated through. Each raster is read in and added to rpcOrthoRasters. This list is then converted to an array. The BuildMosaicRaster ENVI Task is then applied to this array. Results are output to a new folder. Documentation on this task can be found at: https://www.harrisgeospatial.com/docs/ENVIBuildMosaicRasterTask.html. To run this portion of the code, uncomment this chunk (Ctrl + ;) and re-compile. After mosaicking, the FOR loop iterating through all scenes for the AOI is closed. 


  ; OPTIONAL -- Apply mosaicing
  PRINT, STRING(9B) + STRING(9B) + STRCOMPRESS('Mosaicing tiles into single scene (Step 10 of 10)')
  IF ~ FILE_TEST(FILEPATH('8_Mosaic/' + STRMID(fileBasename, 0, STRLEN(fileBasename) - 2) + '_mosaic/' + STRMID(fileBasename, 0, STRLEN(fileBasename) - 2) + '_mosaic.til', ROOT_DIR = workingDir)) THEN BEGIN
      ; List RPC Orthorectified rasters
      rpcOrthoList = FILE_SEARCH(FILEPATH('7_RPC_Ortho/' + STRMID(fileBasename, 0, STRLEN(fileBasename) - 2) + '*_rpcOrtho', ROOT_DIR = workingDir), '*rpcOrtho.til', /FULLY_QUALIFY_PATH)
      ; Create an empty list to populate with rasters
      pcOrthoRasters = List()
      ; Loop through each raster, read it in, and add to rpcOrthoRasters
      FOR k = 0, N_ELEMENTS(rpcOrthoList) - 1 DO BEGIN
        rpcOrthoRaster = e.OpenRaster(rpcOrthoList[k])
        rpcOrthoRasters.Add, rpcOrthoRaster
      ENDFOR
      ; Convert rpcOrthoRasters to an array
      mosaicInputRasters = rpcOrthoRasters.ToArray()
      ; Apply the BuildMosaicRaster task
      Task_mosaic = ENVITask('BuildMosaicRaster')
      Task_mosaic.INPUT_RASTERS = mosaicInputRasters
      Task_mosaic.Execute
      ; Output results into new folder
      mosaicOutput = Task_mosaic.OUTPUT_RASTER
      FILE_MKDIR, FILEPATH('8_Mosaic/' + STRMID(fileBasename, 0, STRLEN(fileBasename) - 2) + '_mosaic/', ROOT_DIR = workingDir)
      mosaicOutput.Export, FILEPATH('8_Mosaic/' + STRMID(fileBasename, 0, STRLEN(fileBasename) - 2) + '_mosaic/' + STRMID(fileBasename, 0, STRLEN(fileBasename) - 2) + '_mosaic.til', ROOT_DIR = workingDir), 'ENVI'
    ENDIF
  
ENDFOR
23. Close ENVI and delete temporary files. Now that processing is complete, ENVI is closed. Deleting the temporary folder created at the beginning of the script has proved problematic, and this error was not resolved even with assistance from Harris Geosptial. Instead, the temporary folder can be manually deleted. Finally, the PRO called at the beginning of the script is closed. 


    ; Close ENVI and delete temporary folder
    e.Close
    ;FILE_DELETE, tempFolder, /RECURSIVE

